HPAVC/HPAVC CD-ROM.iso/YUKONBAT.ZIP/RUN1.BAT

DOS Batch File | 1993-02-28 | 12KB | 441 lines

@Echo Off

REM ┌───────────────────────────────────────────────────────────────┐
REM │ Batch File For Yukon Ho! [phone]  Fido 2:440/59.0      │
REM │      Running RemoteAccess 1.20 and FrontDoor 2.10             │
REM │                 in shell to mailer mode                       │
REM │                                                               │
REM └───────────────────────────────────────────────────────────────┘


REM ┌───────────────────────────────────────────────────────────────┐
REM │  This is where I set the environment variables..............  │
REM └───────────────────────────────────────────────────────────────┘


Set port=2
Set ra=d:\ra
Set fd=d:\fd
Set TCNODE=1
Set spat=c:\utils
Set TZ=GMT0BST
Set CZCONFIG=d:\czip\czip.cfg
Set dszport=2
Set DSZLOG=d:\ra\dsz.log
Set POINTNET=4405
Set tmp=n:\
Set semaj=d:\ra\semaj
Set Pcbdoor=Prodoor
Set ZSE=d:\ra\zcr
Set FDOPT=INTL

ratsr 1


:start

REM ┌──────────────────────────────────────────────────────────────────┐
REM │ Before running the BBS I check for and tidy some files.          │
REM │ I then fire up RA in shell to mailer mode. With the label start. │
REM └──────────────────────────────────────────────────────────────────┘

   d:
   if exist d:\ra\txtfiles\fail.asc del d:\ra\txtfiles\fail.asc
   cd \ra\node1
   ra -m\fd\fd.exe*m -n1 -c2

:process

REM ┌───────────────────────────────────────────────────────────────┐
REM │ Process is where I trap the errorlevels RA & FD exit with..   │
REM └───────────────────────────────────────────────────────────────┘

   if errorlevel 201 goto start
   if errorlevel 200 goto unpackmail
   if errorlevel 90  goto invnet
   if errorlevel 80  goto backup
   if errorlevel 70  goto out
   if errorlevel 60  goto daily
   if errorlevel 55  goto weekly
   if errorlevel 50  goto ranetin
   if errorlevel 45  goto maxmail
   if errorlevel 44  goto almac
   if errorlevel 40  goto vnet
   if errorlevel 15  goto modinit
   if errorlevel 13  goto diskspace
   if errorlevel 12  goto external
   if errorlevel 11  goto internal
   if errorlevel 10  goto finish
   if errorlevel 8   exit
   if errorlevel 7   goto nofossil
   if errorlevel 6   goto xfossil
   if errorlevel 5   goto net&echo
   if errorlevel 4   goto echo_only
   if errorlevel 3   goto net_only
   if errorlevel 2   goto local
   if errorlevel 1   goto error
   if errorlevel 0   goto out
   goto out

:restart_quick

REM ┌──────────────────────────────────────────────────┐
REM │ This is where I return after a type 15 exit      │
REM └──────────────────────────────────────────────────┘

   Ra -R -G
   goto process


:unpackmail

REM ┌─────────────────────────────────────────────────────────────┐
REM │ Before unpacking received mail I check to see if there are  │
REM │ any chatlist's, nodediff's or tic attachs to be processed.  │
REM └─────────────────────────────────────────────────────────────┘

   if exist d:\fd\file\chatlist.* goto cdiff
   if exist d:\fd\file\nodediff.* goto ndiff
   if exist d:\fd\file\*.tic goto tick
   if exist d:\fd\file\*.zic goto tick
   goto inmail

:cdiff

REM ┌───────────────────────────────────────────────────────────────────┐
REM │ Process Chatlist before compiling nodelist                        │
REM └───────────────────────────────────────────────────────────────────┘

   d:
   cd \fd\nodelist
   pak e /wa \fd\file\chatlist.*
   if exist d:\fd\file\nodediff.* goto ndiff
   goto diff

:ndiff

REM ┌────────────────────────────────────────────────────────────────────┐
REM │ Process Nodediff before Compiling Nodelist                         │
REM └────────────────────────────────────────────────────────────────────┘


   d:
   cd \fd\nodelist
   copy \fd\file\nodediff.*
   xlaxdiff /c
   del j:\ibm\mail\nodelist.zip
   pkzip j:\ibm\mail\nodelist nodelist.0* nodelist.1* nodelist.2* nodelist.3*
   rafile update *.* 75
   goto diff

:diff

REM  ┌───────────────────────────────────────────────────────────────┐
REM  │ Compile Nodelist for FrontDoor and RemoteAccess               │
REM  └───────────────────────────────────────────────────────────────┘

   d:
   cd \fd
   fdnc /F
   cd \ra
   ranode policnet.* rnetlist.* frontnet.*
   if exist d:\fd\file\*.tic goto tick
   if exist d:\fd\file\nodediff.* goto tick
   goto inmail

:tick

REM ┌────────────────────────────────────────────────────┐
REM │ Toss incoming Tic file attaches to areas           │
REM └────────────────────────────────────────────────────┘

   d:
   cd\fmgr
   filemgr mgr
   filemgr scan announce
   cd\ra
   rafile import @hd.lst /ERASE /USysop
   if exist d:\fd\file\*.zic goto tick
   goto inmail

:inmail

REM  ┌─────────────────────────────────────────────────────────────┐
REM  │  Import incoming mail. Then checking for Areafix requests   │
REM  │  and linking, before running sys-rec.                       │
REM  └─────────────────────────────────────────────────────────────┘

   d:
   cd\ra
   trans
   cd\fd
   tosscan
   amgrf286
   if errorlevel 1 Tosscan
   tsutil import
   cd\fmgr
   filemgr mgr
   goto start

:net&echo

REM ┌───────────────────────────────────────────────────┐
REM │ Export and pack Echomail and Netmail from msgbase │
REM └───────────────────────────────────────────────────┘

   D:
   tosscan scan
   tsutil export
   goto out

:echo_only

REM ┌────────────────────────────────────────┐
REM │ Export and pack Echomail from msgbase  │
REM └────────────────────────────────────────┘

   D:
   tosscan scan
   goto out

:net_only

REM  ┌──────────────────────────────────────┐
REM  │ Export Netmail(s) from the msgbase.  │
REM  └──────────────────────────────────────┘

   D:
   tsutil export
   goto out

:local

REM  ┌────────────────────────────────┐
REM  │ Fire up the BBS in local mode  │
REM  └────────────────────────────────┘

   d:
   cd \ra\node1
   ra -l -n1
   goto process

:out

REM ┌─────────────────────────────────────────────────────────────┐
REM │  I run some utilities and delete some files between calls   │
REM └─────────────────────────────────────────────────────────────┘

   if exist j:\ibm\pc\downloa?.* del j:\ibm\pc\downloa?.*
   if exist d:\ra\dobbs*.bat del d:\ra\dobbs*.bat
   if exist d:\ra\dsz.log del d:\ra\dsz.log
   d:
   cd \ra
   ezzsa ezzsa.cfg
   cd \ra\node1
   if exist d:\qmx1\*.pkt goto XRSmail
   goto start

:XRSmail

   copy d:\qmx1\*.pkt d:\fd\file
   del d:\qmx\*.pkt
   goto inmail

:daily

REM  ┌─────────────────────────────────────────────────────────────────────┐
REM  │ This is my daily maintenance run. Utilities used are:               │
REM  │ TSutil, Loginfo, Fsumm, Automsg, Popdoor, Remotlog                  │
REM  │ AVTConv, Sys-rec, and RAUser.                                       │
REM  └─────────────────────────────────────────────────────────────────────┘

   d:
   cd\ra\node1
   tsutil
   cd\ra
   rafile import @hd.lst /ERASE
   rafile filelist j:\ibm\lists\02440059.txt @allfiles.lst /Bd:\ra\megalist.hdr
   rafile filelist j:\ibm\lists\giflist.txt @gifs.lst /Bd:\ra\megalist.hdr
   rafile filelist j:\ibm\lists\amiga.txt @amiga.lst /Bd:\ra\megalist.hdr
   rafile filelist j:\ibm\lists\pcfiles.txt @pcfiles.lst /Bd:\ra\megalist.hdr
   rafile filelist j:\ibm\lists\bbsfiles.txt @bbsfiles.lst /Bd:\ra\megalist.hdr
   rafile filelist j:\ibm\lists\stfiles.txt @st.lst /Bd:\ra\megalist.hdr
   rafile filelist j:\ibm\lists\yukonho.new @allfiles.lst /D7
   rafile filelist j:\ibm\lists\mac.txt @mac.lst /Bd:\ra\megalist.hdr
   pkzip j:\ibm\lists\02440059 j:\ibm\lists\02440059.txt
   pkzip j:\ibm\lists\giflist j:\ibm\lists\giflist.txt
   pkzip j:\ibm\lists\yukonnew j:\ibm\lists\yukonho.new
   lha a j:\ibm\lists\amiga j:\ibm\lists\amiga.txt
   pkzip j:\ibm\lists\pcfiles j:\ibm\lists\pcfiles.txt
   pkzip j:\ibm\lists\bbsfiles j:\ibm\lists\bbsfiles.txt
   pkzip j:\ibm\lists\stfiles j:\ibm\lists\stfiles.txt
   pkzip j:\ibm\lists\mac j:\ibm\lists\mac.txt
   rafile update *.* 93
   cd\ra
   cd\ra\txtfiles
   move onceonly.* d:\temp
   avtconv *.ans
   move d:\temp\onceonly.* d:\ra\txtfiles
   d:\ra\ra_activ.exe /c /e
   cd\ra
   rauser -p
   rauser -s
   cd\ra\rats
   rmu.exe
   cd\ra\log
   pkzip ra d:\ra\node1\ra.log
   pkzip fd d:\ra\fd.log
   nmdate d:\ra\log\ra.zip
   nmdate d:\ra\log\fd.zip
   del d:\ra\node1\ra.log
   del d:\ra\fd.log
   cd\fd
   copy setup.fd fd.sys
   goto start

:weekly

REM ┌──────────────────────────────┐
REM │ Weekly maintenance done here │
REM └──────────────────────────────┘

   d:
   cd\ra\node1
   tsutil
   xcopy \ra\*.ra c:\rabak
   xcopy *.ra c:\rabak
   copy run1.bat c:\rabak
   cd\ra\log
   move *.zip c:\rabak\logbak
   goto start


:ranetin

REM ┌─────────────────────────────────────────────┐
REM │ Prepare weekly Ranetlist segment submission │
REM └─────────────────────────────────────────────┘


   d:
   cd\fd
   makenl
   move net7449.* d:\fd\file
   cd\fmgr
   filemgr scan
   goto start


:backup

REM ┌─────────────────────────────────────────────────────────┐
REM │  This is for automated backup's of the BBS partition    │
REM └─────────────────────────────────────────────────────────┘


    d:
    cd\temp
    copy c:\config.sys
    copy c:\autoexec.bat
    cd\
    ctback d:\*.* /v:d /o /s
    goto start


:maxmail

REM ┌────────────────────────────────────────────────────────────────┐
REM │ This is where I use Robocomm to pick up ILink mail and use     │
REM │ Max to process it into the msgbase                             │
REM └────────────────────────────────────────────────────────────────┘

    D:
    del D:\ra\max\work\almac.msg
    del D:\ra\max\work\almac.rep
    cd \ra\max
    max scan
    cd \ra\max\work
    ren almac.rep almac.msg
    pkzip almac.rep almac.msg
    cd\ra\max\out
    copy \ra\max\work\almac.rep
    cd\ra\max\work
    del *.rep
    del *.msg
    cd\ra\max
    robocomm /aAlmac /r
    cd \ra\max\out
    del *.rep
    cd \ra\max\work
    pkunzip a*.q* M*.*
    cd \ra\max
    max toss
    cd \ra\max\work
    del *.q*
    del m*.*
    goto start

:almac

    d:
    cd\ra\max
    robocomm /aAlmac /r
    goto start


:invnet

REM ┌───────────────────┐
REM │Incoming vnet call │
REM └───────────────────┘
    d:
    cd\vbbs
    VNET 1 /HOST
    goto start

:vnet

REM ┌───────────────────────┐
REM │ Automated vnet pickup │
REM └───────────────────────┘

    d:
    cd\vbbs
    call d:\vbbs\net2.bat
    cd\fd
    tosscan toss
    tsutil
    goto start


REM ┌───────────────────────────────────────────────────────────┐
REM │ This is where I log and report exits from the batch file  │
REM └───────────────────────────────────────────────────────────┘


:xfossil
    Echo Incorrect Fossil version..................Bombing out
    goto finish
:nofossil
    Echo No Fossil Present.........................Bombing out
    goto finish
:modinit
    Echo Frontdoor unable to init Modem............Bombing out
    goto finish
:diskspace
    Echo Insufficient disk space for Frontdoor.....Bombing out
    goto finish
:error
    Echo ERROR.....................................Bombing out
    goto finish
:external
    Echo External error in Frontdoor...............Bombing out
    goto finish
:internal
    Echo Internal error in Frontdoor...............Bombing out
    goto finish
:finish
   cd \ra\node1
   echo ..
   echo Yukon Ho! node1 is bye bye